66 lines
2.0 KiB
Kotlin
66 lines
2.0 KiB
Kotlin
import org.jetbrains.intellij.platform.gradle.TestFrameworkType
|
|
|
|
plugins {
|
|
id("java")
|
|
id("org.jetbrains.kotlin.jvm") version "2.4.0"
|
|
id("org.jetbrains.kotlin.plugin.compose") version "2.4.0"
|
|
id("org.jetbrains.kotlin.plugin.serialization") version "2.4.0"
|
|
id("org.jetbrains.intellij.platform") version "2.16.0"
|
|
}
|
|
|
|
group = "com.cruldra"
|
|
version = "0.1.0"
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
intellijPlatform {
|
|
defaultRepositories()
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
intellijPlatform {
|
|
intellijIdeaCommunity("2026.1.3") {
|
|
useInstaller = false
|
|
}
|
|
bundledPlugin("Git4Idea")
|
|
bundledPlugin("org.jetbrains.plugins.terminal")
|
|
testFramework(TestFrameworkType.Platform)
|
|
|
|
// Jewel (Compose for Desktop) ships bundled with the platform since 251.2+
|
|
bundledModule("intellij.platform.jewel.foundation")
|
|
bundledModule("intellij.platform.jewel.ui")
|
|
bundledModule("intellij.platform.jewel.ideLafBridge")
|
|
bundledModule("intellij.libraries.compose.foundation.desktop")
|
|
bundledModule("intellij.libraries.compose.runtime.desktop")
|
|
bundledModule("intellij.libraries.skiko")
|
|
}
|
|
|
|
implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.11.0") {
|
|
exclude(group = "org.jetbrains.kotlinx", module = "kotlinx-coroutines-core")
|
|
}
|
|
|
|
testImplementation("junit:junit:4.13.2")
|
|
}
|
|
|
|
intellijPlatform {
|
|
pluginConfiguration {
|
|
ideaVersion {
|
|
sinceBuild = "261"
|
|
untilBuild = provider { null }
|
|
}
|
|
}
|
|
}
|
|
|
|
kotlin {
|
|
jvmToolchain(21)
|
|
}
|
|
|
|
// 已知状态字段从 VS Code 插件、spx CLI 共用的 [状态 schema](vscode/schemas/state-json.schema.json) 派生：
|
|
// 构建时把它打进资源，和 [状态评论编解码器](jetbrains/src/main/kotlin/com/cruldra/superworkbench/model/IssueStateJson.kt#IssueStateJson) 同包，不另存副本。
|
|
tasks.processResources {
|
|
from("../vscode/schemas/state-json.schema.json") {
|
|
into("com/cruldra/superworkbench/model")
|
|
}
|
|
}
|